Chapter 10 - The Geometry of Linear and Affine Maps

Section 10.3 - The Effect of Linear Maps on Volume, Area, and Arclength in (R^3)

Example 10.3.1

P={-4,7,3};Q={11,-6,2};R={9,13,-5};

(PQR=Transpose[{P,Q,R}])//MatrixForm

TP={5,2,-9};TQ={-1,3,8};TR={3,-6,7};

(TPTQTR=Transpose[{TP,TQ,TR}])//MatrixForm

(A=TPTQTR.Inverse[PQR])//MatrixForm

{A.P,A.Q,A.R}

TrianglePQR=Graphics3D[{Blue,Opacity[.5],Polygon[{P,Q,R}]}];

TriangleTPTQTR=Graphics3D[{Red,Opacity[.5],Polygon[{TP,TQ,TR}]}];

TxtPlots=Graphics3D[{Black,Text["P",{-4,7,4}],Text["Q",{11,-6,3}],Text["R",{9,13,-6}],Text["TP",{5,2,-10}],Text["TQ",{-1,3,9}],Text["TR",{3,-6,8}]}];

Show[TrianglePQR,TriangleTPTQTR,TxtPlots]

Example 10.3.2

LengthPQ=N[Norm[Q-P]]

LengthTPTQ=N[Norm[TQ-TP]]

LengthTPTQ/LengthPQ

N[{Det[A],Sqrt[Abs[Det[A]]],(((Abs[Det[A]]))^(1/3))}]

LengthPR=N[Norm[R-P]]

LengthTPTR=N[Norm[TR-TP]]

LengthTPTR/LengthPR

LengthQR=N[Norm[R-Q]]

LengthTQTR=N[Norm[TR-TQ]]

LengthTQTR/LengthQR

(LengthTPTQ/LengthPQ+LengthTPTR/LengthPR+LengthTQTR/LengthQR)/3

AreaPQR=0.5 Norm[Cross[Q-P,R-P]]

AreaTPTQTR=0.5 Norm[Cross[TQ-TP,TR-TP]]

AreaTPTQTR/AreaPQR

N[{Sqrt[Abs[Det[A]]],(((Abs[Det[A]]))^(2/3))}]

ParallelepipedPQR=Graphics3D[{Blue,Opacity[.5],Polygon[{{0,0,0},Q,P+Q,P}],Polygon[{Q,R+Q,P+Q+R,P+Q}],Polygon[{R+Q,P+Q+R,P+R,R}],Polygon[{P,P+Q,P+Q+R,P+R}],Polygon[{{0,0,0},R,P+R,P}],Polygon[{{0,0,0},Q,R+Q,R}]}];

ParallelepipedTPTQTR=Graphics3D[{Red,Opacity[.5],Polygon[{{0,0,0},TQ,TP+TQ,TP}],Polygon[{TQ,TR+TQ,TP+TQ+TR,TP+TQ}],Polygon[{TR+TQ,TP+TQ+TR,TP+TR,TR}],Polygon[{TP,TP+TQ,TP+TQ+TR,TP+TR}],Polygon[{{0,0,0},TR,TP+TR,TP}],Polygon[{{0,0,0},TQ,TR+TQ,TR}]}];

Show[ParallelepipedPQR,ParallelepipedTPTQTR, TxtPlots]

VolumePQR=Abs[Det[{P,Q,R}]]

VolumeTPTQTR=Abs[Det[{TP,TQ,TR}]]

N[{VolumeTPTQTR/VolumePQR,Det[A]}]

Example 10.3.3

A={{-8,5,-3},{7,2,-9},{1,6,4}};

R={5 Cos[u] Sin[v]+8,5 Sin[u] Sin[v]+2,5 Cos[v]+4};

Ru=D[R,u]

Rv=D[R,v]

Integ=Simplify[Factor[TrigExpand[Det[{R,Ru,Rv}]]]]

VolumeR=Abs[N[1/3 Integrate[Integ,{u,0,2π},{v,0,π}]]]

N[4/3 π (5^3)]

TR=A.R;

TRu=D[TR,u]

TRv=D[TR,v]

IntegT=Simplify[TrigExpand[Det[{TR,TRu,TRv}]]]

VolumeTR=Abs[N[1/3 Integrate[IntegT,{u,0,2π},{v,0,π}]]]

Abs[Det[A]] VolumeR

Abs[Det[A]]

PlotRTR=ParametricPlot3D[{R,TR},{u,0,2 π},{v,0,π},PlotStyle->{Red,Blue},Mesh->None]

IntegR=Simplify[Sqrt[TrigExpand[Sum[(((Cross[Ru,Rv][[k]]))^2),{k,1,3}]]]]

SurfaceAreaR=Integrate[IntegR,{u,0,2π},{v,0,π}]

4 π (5^2)

IntegTR=Simplify[Sqrt[TrigExpand[Sum[(((Cross[TRu,TRv][[k]]))^2),{k,1,3}]]]]

SurfaceAreaTR=NIntegrate[IntegTR,{u,0,2 π},{v,0,π}]

SurfaceAreaTR/SurfaceAreaR

N[{Sqrt[Abs[Det[A]]],((Abs[Det[A]])^(2/3))}]