Chapter 4 - Applications of Linear Systems and Matrices

Section 4.4 - Applications of Matrix Multiplication to Geometry

Example 4.4.1

CircPlot=Graphics[{Blue,Thickness[0.01],Circle[{0,0},5]}];

P={5 Cos[π/6],5 Sin[π/6]};

Q={5 Cos[π/6+4 π/5],5 Sin[π/6+4 π/5]};

Arc=Graphics[{Red,Thickness[0.015],Circle[{0,0},5,{π/6,π/6+4 π/5}]}];

Angles=Graphics[{Black,Thickness[0.010],Circle[{0,0},1.8,{π/6,π/6+4 π/5}],Circle[{0,0},2.5,{0,π/6}]}];

PtsPlot=Graphics[{PointSize[0.05],Black,Point[{P,Q}]},Axes->True];

TxtPlot=Graphics[{Black,Text["P",{5.3,2.5}],Text["Q",{-5.5,0.5}],Text["θ", {-0.4,0.7}],Text["ϕ", {1.7,0.45}]}];

Lines=Graphics[{Black,Thickness[0.010],Line[{P,{0,0},Q}]}];

Show[CircPlot,Arc,PtsPlot,TxtPlot,Lines,Angles,Axes->True]

TrigExpand[Cos[ϕ+θ]]

TrigExpand[Sin[ϕ+θ]]

(P={{4.330127020},{2.5}})//MatrixForm

A={{Cos[θ],-Sin[θ]},{Sin[θ],Cos[θ]}};

(A.P/.{θ->4 π/5})//MatrixForm

Example 4.4.2

F=(3 Cos[4 t]+2) 2 Cos[t]+5;

G=(3 Cos[4 t]+2) 2 Sin[t]+12;

OrigPlot=ParametricPlot[{F,G},{t,0,2π},PlotStyle->{Blue,Thickness[0.01]}];

center={{-4},{-9}};

(P={{F},{G}})//MatrixForm

Q=(A.(P-center)+center)/.{θ->7π/8}

RotatePlot=ParametricPlot[Flatten[Q],{t,0,2π},PlotStyle->{Red,Thickness[0.01]}];

CenterPlot=ListPlot[{Flatten[center]},PlotMarkers->{"+",Medium}];

Show[OrigPlot,RotatePlot,CenterPlot,PlotRange->All]

QArb=A.(P-center)+center

QArb/.{θ->7 π/8}

Manipulate[QArbExp=Evaluate[QArb/.{θ->thetaval}];
QArbExpPlot=ParametricPlot[Flatten[QArbExp],{t,0,2π},PlotStyle->{Black,Thickness[0.01]}];
Show[OrigPlot,QArbExpPlot,RotatePlot,PlotRange->{{-40,25},{-40,25}}],{{thetaval,0,θ},0,7 π/8,π/16}]