Chapter 7 - A Few Advanced Vector Algebra Topics

Section 7.2 - “Rolling” a Circle Along a Curve

Example 7.2.1

Bv={t,3 Sin[t]};

BPlot=ParametricPlot[Bv,{t,-1,7},PlotStyle->{Thickness[0.005],Black}];

TanBv=D[Bv,t]

PerpP={-TanBv[[2]],TanBv[[1]]}

UnitPerpU=PerpP/Norm[PerpP]

TanBv.PerpP

R=0.3;

CntrV=Bv+R UnitPerpU

CntrVals=Table[CntrV,{t,0,6}]

CntrPlots=ListPlot[{CntrVals},PlotMarkers->{"+", Medium},PlotStyle->Red];

CirclePlots=Table[ParametricPlot[CntrVals[[k]]+R {Cos[s],Sin[s]},{s,0,2π},PlotStyle-> Blue],{k,1,7}];

Show[BPlot,CntrPlots,CirclePlots,PlotRange->{{-1,7},{-4,4}}]

Manipulate[CenterVal=Evaluate[CntrV/.{t->tval}];
CenterValPlot=ListPlot[{CenterVal},PlotMarkers->{"+", Medium},PlotStyle-> Red];
CircleValPlot=ParametricPlot[CenterVal+R {Cos[s],Sin[s]},{s,0,2π},PlotStyle->Blue];
Show[BPlot,CenterValPlot,CircleValPlot,PlotRange->{{-1,7},{-4,4}}],{{tval,0,"t"},0,2π,π/16}]

Example 7.2.2

X=2 (E^(-0.2 t))Cos[t];

Y=2 (E^(-0.2 t))Sin[t];

DX=D[X,t]

DY=D[Y,t]

D2X=D[X,{t,2}]

D2Y=D[Y,{t,2}]

κ=Abs[DX D2Y-D2X DY]/(((((DX^2)+(DY^2)))^(3/2)));

Plot[κ,{t,0,5π}]

PositionV={X,Y};

TangentV={DX,DY}/Sqrt[(DX^2)+(DY^2)];

NormalV=D[TangentV,t]/Norm[D[TangentV,t]];

EndPointV=PositionV+(1/κ)NormalV;

SpiralPlot=ParametricPlot[PositionV,{t,0,5π},PlotRange->{{-2,2},{-2,2}},PlotStyle->{Black,Thickness[0.01]}];

CntrRadPlots=Graphics[{PointSize[0.03],Blue,Point[{EndPointV/.t->π/2,PositionV/.t->π/2}]}];

LinePlot=Graphics[{Thickness[.005],Blue,Line[{EndPointV/.t->π/2,PositionV/.t->π/2}]}];

CircleκPlot=ContourPlot[Evaluate[((((x-EndPointV[[1]]))^2)+(((y-EndPointV[[2]]))^2)==((((1/κ)))^2))/.t->π/2],{x,-2,2},{y,-2,2},ContourStyle->{Red,Thickness[0.007]},PlotRange->All,Axes->True,Frame->False];

Show[SpiralPlot,CircleκPlot,CntrRadPlots,LinePlot]

Manipulate[EndPointVal=Evaluate[EndPointV/.{t->tval}];
CntrRadValPlot=Graphics[{PointSize[0.02],Blue,Point[{EndPointVal,Evaluate[PositionV/.t->tval]}]}];
LineValPlot=Graphics[{Thickness[.005],Blue,Line[{EndPointVal,Evaluate[PositionV/.t->tval]}]}];
CircleκValPlot=ContourPlot[Evaluate[((((x-EndPointVal[[1]]))^2)+(((y-EndPointVal[[2]]))^2)==((((1/κ)))^2))/.t->tval],{x,-3,3},{y,-3,3},ContourStyle->{Red,Thickness[0.007]},PlotRange->All, Axes->True,Frame->False,PlotPoints->50,MaxRecursion->2];
Show[SpiralPlot,CircleκValPlot,CntrRadValPlot,LineValPlot,PlotRange->{{-3,3},{-3,3}}],{{tval,0,"t"},0,5π,π/4}]